@echo off
rem Запуск одной доли кампании kbc2d на этой машине: shard.bat 3
rem Нужны: драйвер видеокарты и Docker Desktop (бэкенд WSL2). Рядом должен лежать
rem docker-compose.shards.yml. Результаты появятся в папке out рядом с этим файлом.
chcp 65001 >nul
setlocal
cd /d "%~dp0"

set "N=%~1"
if "%N%"=="" goto usage
if "%N%"=="1" goto ok
if "%N%"=="2" goto ok
if "%N%"=="3" goto ok
if "%N%"=="4" goto ok
if "%N%"=="5" goto ok
:usage
echo Использование: shard.bat ^<номер доли 1..5^>
echo   shard.bat 3     поднять долю 3 и смотреть её журнал
echo Остановить: docker compose -f docker-compose.shards.yml stop
exit /b 2

:ok
if not exist docker-compose.shards.yml (
  echo Рядом с shard.bat нет docker-compose.shards.yml.
  exit /b 1
)
docker info >nul 2>&1
if errorlevel 1 (
  echo Docker не отвечает. Запустите Docker Desktop, дождитесь зелёного статуса и повторите.
  exit /b 1
)

docker compose -f docker-compose.shards.yml up -d shard%N%
if errorlevel 1 exit /b 1
echo.
echo Доля %N% запущена и считает в фоне. Журнал ниже; Ctrl+C закрывает только журнал,
echo счёт продолжается. Результаты: %CD%\out
echo.
docker compose -f docker-compose.shards.yml logs -f shard%N%